Pang

File1
ClrGraph
ViewWindow 1,127,0,63,1,0
AxesOff
Green Text 2,74,"By: B.Conijn"
Text 10,10,"1:Single Player"
Text 20,10,"2:Multi Player"
Text 30,10,"A~F:Load Game"
Orange Text 50,10,"While Playing=>A~F:Save Game"
Orange F-Line 118,9,78,9
Orange F-Line 118,9,118,35
Orange F-Line 118,35,78,35
Orange F-Line 78,9,78,35
F-Line 79,34,117,34
F-Line 79+20Ran#,33,117,33
F-Line 117-20Ran#,32,117,32
Green F-Line 100,25,103,28
Green F-Line 100,30,102,28
Green F-Line 104,28,106,30
Green F-Line 100,31,100,34
Green F-Line 106,31,106,34
0->rho
0->tau
AxesOn
Do
Getkey->G
G=72=>2->tau
G=72=>1->rho
G=62=>1->rho
If Frac (.1G)=.6
Then Green Text 37,30,"Loading..."
8-.1(G-6)->L
File6
L=1=>List 1
L=2=>List 2
L=3=>List 3
L=4=>List 4
L=5=>List 5
L=6=>List 6
File1
Seq(Intg (.01+64Frac (List Ans[Intg (X/5)+1]*64^(5Frac (X/5)))),X,0,126,1)->List 1
10Frac (List Ans[27]/10)->P
Intg (List Ans[27]/10)->tau
List Ans[28]->G
List Ans[29]->H
256Frac (List Ans[30]/256)->I
Intg (List Ans[30]/256)->J
256Frac (List Ans[31]/256)->K
Intg (List Ans[31]/256)->L
256Frac (List Ans[32]/256)->M
Intg (List Ans[32]/256)->N
{0}
2->rho
IfEnd
LpWhile rho=0
File1
ClrGraph
ViewWindow 1,127,0,63,1,0
AxesOff
If rho=1
Then 127->Dim List 1
30Ran#+28->U
50Ran#+2->V
30Ran#+28->W
For 1->A To 63
(A-63)^2->B
(A-10)^2->C
Intg ((UB+VC)/(B+C))->F
F-Line A,F,A,63
F->List 1[A]
Next
For 64->A To 127
(A-117)^2->B
(A-63)^2->C
Intg ((VB+WC)/(B+C))->F
F-Line A,F,A,63
F->List 1[A]
Next
Intg U-4->M
Intg W-4->N
135->I
225->J
Else For 1->A To 127
F-Line A,List 1[A],A,63
Next
IfEnd
(M-N)/40->Q
Deg
Green F-Line 10,M,10+4.2sin I,M+4.2cos I:Green F-Line 117,N,117+4.2sin J,N+4.2cos J:Green F-Line 9,M,7,M+2:Green F-Line 118,N,120,N+2:Green F-Line 11,M,13,M+2:Green F-Line 116,N,114,N+2:Green F-Line 13,M+3,13,63:Green F-Line 120,N+3,120,63:Green F-Line 7,M+3,7,63:Green F-Line 114,N+3,114,63
If rho=1
Then 100->G:100->H
Intg (2Ran#+1)->P
20->K
20->L
IfEnd
Green F-Line 41,2,86,2
Green F-Line 46,1,46,3
Green F-Line 53,1,53,3
Green F-Line 60,1,60,3
Green F-Line 67,1,67,3
Green F-Line 74,1,74,3
Green F-Line 81,1,81,3
While Intg G>0 And Intg H>0
3-P->P
Intg log G->F:Green Text 1,5+4F,"% ":Green Text 1,1,Intg G:Intg log H->F:Green Text 1,106,"    %":Green Text 1,118-4F,Intg H
If P=1
Then I->A:K->B:M->D:10->C
Else J->A:L->B:N->D:117->C
IfEnd
40->Z
Orange Text 58,1,"Angle:"
Orange Text 58,42,"Power:"
Orange Text 58,122,P
0->U
0->V
A->S
.2Ran#-.1->W
63.5+175W->O
Orange F-Line O,1,O,3
While Z<>31
If Z>=20
Then If A<>U
Then Orange Text 58,26,A
0->T
IfEnd
B<>V=>Orange Text 58,68,B
IfEnd
A<>S=>Isz T
If T=5
Then Isz T
Green Text D-6,C-5,"   "
Green F-Line C,D,C+4.2sin A,D+4.2cos A
A->S
IfEnd
A->U:B->V
If tau=2 And P=2
Then Z=20=>0->Z
If Z=40
Then Pol(4-Q,(-)2.6-20W)->List 2
180-5Intg (.2List 2[2]+.9)->A
Intg (5List 2[1])->B
0->S
20->Z
IfEnd
T=6=>31->Z
Else Getkey->Z
Z=37=>B-1->B
Z=38=>A+5->A
Z=27=>A-5->A
Z=28=>B+1->B
If Frac (.1Z)=.6
Then Orange Text 10,10,"Saving..."
8-.1(Z-6)->Z
Seq(List 1[Intg (127Frac (5X/127)+1.5)]/64+List 1[Intg (127Frac ((5X+1)/127)+1.5)]/4096+List 1[Intg (127Frac ((5X+2)/127)+1.5)]/262144+List 1[Intg (127Frac ((5X+3)/127)+1.5)]/16777216+List 1[Intg (127Frac ((5X+4)/127)+1.5)]/64^5,X,0,25,1)
Seq(List Ans[Intg (26Frac (X/26)+1.5)],X,0,31,1)->List 2
3-P+10tau->List 2[27]
G->List 2[28]
H->List 2[29]
I+256J->List 2[30]
K+256L->List 2[31]
M+256N->List 2[32]
List 2
File6
Z=1=>List Ans->List 1
Z=2=>List Ans->List 2
Z=3=>List Ans->List 3
Z=4=>List Ans->List 4
Z=5=>List Ans->List 5
Z=6=>List Ans->List 6
File1
{0}->List 2
{0}
Orange Text 10,10,"          "
IfEnd
IfEnd
B=9=>10->B
A=95=>100->A
A=265=>260->A
B=41=>40->B
WhileEnd
If P=1
Then A->I:B->K
Else A->J:B->L
IfEnd
Orange Text 58,1,"                    "
.2B->B
Bsin A->S
Bcos A->T
C+3sin A->C
D+3cos A->D
1->R
C->E
D->F
While R>0
If Intg C<128 And Intg C>0 And Intg D<64
Then If List 1[Intg C]>=Intg D
Then C+S->C
D+T->D
Orange F-Line Intg C,Intg D,E,F
S+W->S
T+.2->T
Intg C->E
Intg D->F
Else (-)1->R
IfEnd
Else 0->R
IfEnd
WhileEnd
If R=(-)1
Then Intg (C-.5S-1)->E
E<1=>1->E
E>124=>124->E
List 1[E]->F
List 1[E+3]<F=>List 1[E+3]->F
Abs (List 1[E]-List 1[E+3])>2=>Isz F
F-3->F
F>58=>58->F
F<1=>1->F
Text F,E," "
F+6->F
List 1[E]<F=>F->List 1[E]
List 1[E+1]<F=>F->List 1[E+1]
List 1[E+2]<F=>F->List 1[E+2]
List 1[E+3]<F=>F->List 1[E+3]
IfEnd
5-Abs (C-.5S-10.5)->O
O>0=>G-10O->G
5-Abs (C-.5S-116.5)->O
O>0=>H-10O->H
For 0->A To 10
Orange Text 6A+1,1,"                "
Orange Text 6A+1,64,"                "
Next
WhileEnd
Text 29,32," Player   Wins!"
G<=0=>2->P
H<=0=>1->P
P=1=>Green Text 1,107,"     "
P=2=>Green Text 1,1,"     "
Green Text 29,65,P
AxesOn